use Timer::Breakable;
use OO::Monitors;



head

Timer::Stopwatch - Schedule and reset repeated time measurements


code

=begin code

use Timer::Stopwatch;

my $irregular-supply = Supply.interval(1).grep: { Bool.pick }

my $timer = Timer::Stopwatch.new;
react {
    whenever $irregular-supply {
        note "{ now.DateTime.hh-mm-ss }: Received an irregular event";

        # Wait up to 2 seconds for the next event
        $timer.reset: 2;
    }
    whenever $timer {
        note "It's been { .round } seconds since the last event";
        $timer.stop;
    }
    whenever Promise.in: 20 {
        note 'Stopping after 20 seconds';
        $timer.stop;
    }
    whenever $timer.Promise {
        note "Timer was stopped. We're done";
        done;
    }
}

# OUTPUT:
# 20:33:39: Received an irregular event
# 20:33:40: Received an irregular event
# 20:33:42: Received an irregular event
# It's been 2 seconds since the last event
# Timer was stopped. We're done

=end code


Timer::Stopwatch is a resettable, stoppable wrapper around a Supply
that can be used to mark multiple moments in time.



unit monitor Timer::Stopwatch:ver<0.1.0>:auth<zef:jjatria>;

has Promise          $!done     .= new;
has Supplier         $!supplier .= new;
has Instant          $!start     = now;
has Timer::Breakable $!timer;




#|(
    Creates a new Stopwatch with a timer that will trigger in the
    given amount of seconds, unless it is reset or stopped before that.
)
method in ( ::?CLASS:U: Numeric $in --> Timer::Stopwatch ) {
    self.bless: :$in;
}

submethod TWEAK (:$in) {
    $!timer = Timer::Breakable.start: $in, { self.tick } if $in;
}

#|(
    Emits the duration since creation time (or the last C<reset>)
    to the Supply. Returns the emitted Duration.
)
method tick ( ::?CLASS:D: --> Duration ) {
    my $dur = self.Duration;
    $!supplier.emit: $dur;
    return $dur;
}

#|(
    Reset sets the start time for the stopwatch to the current time.
    If called with a numeric argument, it also sets a timer to expire
    after the given duration.

    It returns True if the call interrupted a pending timer, and False if
    no timer had been set, or if it had already expired, or if the stopwatch
    had already been stopped.
)
method reset ( ::?CLASS:D: Numeric $in? --> Bool ) {
    return False if $!done;
    $!start = now;
    my $status = self!stop;
    $!timer = Timer::Breakable.start: $in, { self.tick } if $in;
    return $status;
}

#|(
    Stop marks this stopwatch as done. Once a stopwatch has been stopped,
    most of its actions are finished, and new stopwatch should be created.
    Internally, it stops any pending timers and closes the supply.

    It returns True if the call interrupted a pending timer, and False if
    no timer had been set, or if it had already expired, or if the stopwatch
    had already been stopped.
)
method stop ( ::?CLASS:D: --> Bool ) {
    return False if $!done;
    $!supplier.done;
    $!done.keep: self.Duration;
    return self!stop;
}

#|(
    Returns the amount of time elapsed since the start (or the last reset)
    as a Duration.
)
method Duration ( ::?CLASS:D: --> Duration ) { now - $!start }

#|(
    Returns a Promise that will be kept when the Stopwatch is stopped.
    When kept, it will hold the Duration elapsed since the time the
    Stopwatch was created, or since the last call to C<reset>.
)
method Promise ( ::?CLASS:D: --> Promise ) { $!done }

#| Returns a live Supply that will receive timer events
method Supply ( ::?CLASS:D: --> Supply ) { $!supplier.Supply }

# Private methods

# Private stop method. Called from reset and stop. Returns False if no timer
# is set, or if the timer is still running. Otherwise, it stops the timer and
# returns True.
method !stop ( ::?CLASS:D: --> Bool ) {
    return False unless $!timer;
    $!timer.stop;
    return True;
}



This library is free software; you can redistribute it and/or modify it
under the Artistic License 2.0.


root

README

React

=begin React :component<HeaderCol> :id<menu> 
=para L<Documentation|/doc/introduction>
=para L<Modules| /mods>
=para L<Examples| file:../examples/index.podlite>
=para L<Download |file:../download/index.podlite>
=para L<About|file:../about/index.podlite>
=para 🔍 K<⌘K>/K<ctrl-K>
=end React


=begin React :component<HeaderCol> :id<footer>  
=begin nested :!nested
=item1 B<Language>
    =item2 L<Get started|file:../getting-started/getting-started.podlite>
    =item2 L<Why Raku?|/doc/language/faq#Why-should-I-learn-Raku-What's-so-great-about-it>
    =item2 L<Try Raku|https://glot.io/new/raku>
    =item2 L<Raku cheat sheet|https://github.com/Raku/mu/blob/master/docs/Perl6/Cheatsheet/cheatsheet.txt>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<Raku on Exercism|https://exercism.org/tracks/raku>
    =item2 L<Wikipedia|https://en.wikipedia.org/wiki/Raku_(programming_language)>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=end nested
=begin nested :!nested

=item1 B<L<Documentation|/doc>>
    =item2 L<Getting started, Migration guides from other languages, & Tutorials | file:../doc/introduction.podlite>
    =item2 L<Language References|file:../doc/reference.podlite>
    =item2 L<Type Reference| file:../doc/types.podlite>
    =item2 L<Miscellaneous| file:../doc/miscellaneous.podlite>
    =item2 L<FAQs (Frequently Asked Questions)|/doc/language/faq>
    =item2 L<Community|/doc/language/community>
    =item2 L<The list of all documents|file:../doc/index.podlite>

=item1 B<Resources>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>

=end nested
=begin nested :!nested

=item1 B<Resoures>
    =item2 L<Download | file:../download/index.podlite>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=item1 B<Learning>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Wikibook |https://en.wikibooks.org/wiki/Raku_Programming>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>
    =item2 L<Learn Raku in Y minutes|https://learnxinyminutes.com/docs/raku/>
    =item2 L<Golfing |https://github.com/AlexDaniel/raku-golf-cheatsheet>
=end nested
=begin nested :!nested

=item1 B<Explore>
    =item2 L<Raku Blog Aggregator|https://planet.raku.org/>
    =item2 L<Rakudo Weekly|https://rakudoweekly.blog/>
    =item2 L<The Weekly Challenge |https://perlweeklychallenge.org/>
    =item2 L<Raku Advent Calendar|https://raku-advent.blog/>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=end nested
=end React


=begin React :component<CookieConsent> :id<CookieConsent> :buttonCaption("Got it!")
=para
This website uses cookies for analytics.
=end React


Stopwatch

NAME

SYNOPSIS

DESCRIPTION

METHODS

AUTHOR

COPYRIGHT AND LICENSE

Timer::Stopwatch v0.1.0

Authors

License

Dependencies

Test Dependencies

Provides

Documentation