para

use v6.d;

module Hash::LRU:ver<0.0.5>:auth<zef:lizmat> {

    # The basic logic for keeping LRU data up-to-date
    my role basic {
        method AT-KEY(::?CLASS:D: \key) is raw is hidden-from-backtrace {
            self!SEEN-KEY(key) if self.EXISTS-KEY(key);
            nextsame
        }
        method ASSIGN-KEY(::?CLASS:D: \key, \value) is hidden-from-backtrace {
            self!SEEN-KEY(key);
            nextsame
        }
        method BIND-KEY(::?CLASS:D: \key, \value) is hidden-from-backtrace {
            self!SEEN-KEY(key);
            nextsame
        }
        method STORE(\to_store) is hidden-from-backtrace {
            callsame;
            self!INIT-KEYS;
            self!SEEN-KEY($_) for self.keys;
            self
        }
    }

    # The role to be applied when a specific limit is given for hashes
    my role limit-given-hash[$max] does basic {
        my int $max-elems = $max;  # cannot parameterize to a native int yet
        has str @!keys;

        method !INIT-KEYS(--> Nil) {
            @!keys = ();
        }

        method !SEEN-KEY(Str(Any) $key --> Nil) {
            if @!keys.elems -> int $elems {
                my int $i = -1;
                Nil while ++$i < $elems && @!keys.AT-POS($i) ne $key;
                if $i < $elems {
                    @!keys.splice($i,1);
                }
                elsif $elems == $max-elems {
                    self.DELETE-KEY(@!keys.pop);
                }
            }
            @!keys.unshift($key);
        }
    }

    # The role to be applied when a specific limit is given for object hashes
    my role limit-given-object-hash[$max] does basic {
        my int $max-elems = $max;  # cannot parameterize to a native int yet
        has str @!whiches;
        has @!keys;

        method !INIT-KEYS(--> Nil) {
            @!whiches = ();
            @!keys    = ();
        }

        method !SEEN-KEY(\key --> Nil) {
            my str $WHICH = key.WHICH;
            if @!whiches.elems -> int $elems {
                my int $i = -1;
                Nil while ++$i < $elems && @!whiches.AT-POS($i) ne $WHICH;
                if $i < $elems {
                    @!whiches.splice($i,1);
                    @!keys.splice($i,1);
                }
                elsif $elems == $max-elems {
                    @!whiches.pop;
                    self.DELETE-KEY(@!keys.pop);
                }
            }
            @!whiches.unshift($WHICH);
            @!keys.unshift(key);
        }
    }

    # Handle the "is LRU" / is LRU(Bool:D) cases
    multi sub trait_mod:<is>(Variable:D \v, Bool:D :$LRU!) is export {
        die "Can only apply 'is LRU' on a Hash, not a {v.var.WHAT}"
          unless v.var.WHAT ~~ Hash;
        my $name = v.var.^name;
        if $LRU {
            trait_mod:<does>(v, v.var.keyof =:= Str(Any)
              ?? limit-given-hash[100]
              !! limit-given-object-hash[100]
            );
            v.var.WHAT.^set_name("$name\(LRU)");
        }
    }

    # Handle the "is LRU(elements => N)" case
    multi sub trait_mod:<is>(Variable:D \v, :%LRU!) is export {
        die "Can only apply 'is LRU' on a Hash, not a {v.var.WHAT}"
          unless v.var.WHAT ~~ Hash;
        my $name = v.var.^name;

        if %LRU<elements>:exists {
            with %LRU<elements> {
                trait_mod:<does>(v, v.var.keyof =:= Str(Any)
                  ?? limit-given-hash[$_]
                  !! limit-given-object-hash[$_]
                );
            }
            else {
                die "Cannot use an undefined value for 'elements' in 'is LRU'. "
                    ~ 'Did you try to set it at runtime?';
            }
        }
        elsif %LRU.keys.sort -> @keys {
            die "Don't know what to do with '{ @keys }' in 'is LRU'";
        }
        v.var.WHAT.^set_name("$name\(LRU)");
    }
}



head

Hash::LRU - trait for limiting number of keys in hashes by usage


my %h is LRU;   # defaults to elements => 100


my %h is LRU(elements => 42);  # note: value must be known at compile time!


my %h{Any} is LRU;  # object hashes also supported


Hash::LRU provides a C<is LRU> trait on C<Hash>es as an easy way to limit
the number of keys kept in the C<Hash>.  Keys will be added as long as
the number of keys is under the limit.  As soon as a new key is added that
would exceed the limit, the least recently used key is removed from the
C<Hash>.


Both "normal" as well as object hashes are supported.


%h<name>       = "Alex";
%h<language>   = "Raku";
%h<occupation> = "devops";
%h<location>   = "Russia";


say %h.raku;
# {:location("Russia"), :occupation("devops"), :language("Raku")}


Source can be located at: https://github.com/lizmat/Hash-LRU . Comments and
Pull Requests are welcome.


This library is free software; you can redistribute it and/or modify it under
the Artistic License 2.0.


root

README

React

=begin React :component<HeaderCol> :id<menu> 
=para L<Documentation|/doc/introduction>
=para L<Modules| /mods>
=para L<Examples| file:../examples/index.podlite>
=para L<Download |file:../download/index.podlite>
=para L<About|file:../about/index.podlite>
=para 🔍 K<⌘K>/K<ctrl-K>
=end React


=begin React :component<HeaderCol> :id<footer>  
=begin nested :!nested
=item1 B<Language>
    =item2 L<Get started|file:../getting-started/getting-started.podlite>
    =item2 L<Why Raku?|/doc/language/faq#Why-should-I-learn-Raku-What's-so-great-about-it>
    =item2 L<Try Raku|https://glot.io/new/raku>
    =item2 L<Raku cheat sheet|https://github.com/Raku/mu/blob/master/docs/Perl6/Cheatsheet/cheatsheet.txt>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<Raku on Exercism|https://exercism.org/tracks/raku>
    =item2 L<Wikipedia|https://en.wikipedia.org/wiki/Raku_(programming_language)>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=end nested
=begin nested :!nested

=item1 B<L<Documentation|/doc>>
    =item2 L<Getting started, Migration guides from other languages, & Tutorials | file:../doc/introduction.podlite>
    =item2 L<Language References|file:../doc/reference.podlite>
    =item2 L<Type Reference| file:../doc/types.podlite>
    =item2 L<Miscellaneous| file:../doc/miscellaneous.podlite>
    =item2 L<FAQs (Frequently Asked Questions)|/doc/language/faq>
    =item2 L<Community|/doc/language/community>
    =item2 L<The list of all documents|file:../doc/index.podlite>

=item1 B<Resources>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>

=end nested
=begin nested :!nested

=item1 B<Resoures>
    =item2 L<Download | file:../download/index.podlite>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=item1 B<Learning>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Wikibook |https://en.wikibooks.org/wiki/Raku_Programming>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>
    =item2 L<Learn Raku in Y minutes|https://learnxinyminutes.com/docs/raku/>
    =item2 L<Golfing |https://github.com/AlexDaniel/raku-golf-cheatsheet>
=end nested
=begin nested :!nested

=item1 B<Explore>
    =item2 L<Raku Blog Aggregator|https://planet.raku.org/>
    =item2 L<Rakudo Weekly|https://rakudoweekly.blog/>
    =item2 L<The Weekly Challenge |https://perlweeklychallenge.org/>
    =item2 L<Raku Advent Calendar|https://raku-advent.blog/>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=end nested
=end React


=begin React :component<CookieConsent> :id<CookieConsent> :buttonCaption("Got it!")
=para
This website uses cookies for analytics.
=end React


LRU

NAME

SYNOPSIS

DESCRIPTION

EXAMPLE

AUTHOR

COPYRIGHT AND LICENSE

Hash::LRU v0.0.5

Authors

License

Dependencies

Test Dependencies

Provides

Documentation