para

use v6;

# This program demonstrates using Font::FreeType with MagicWand.
# It uses the font metrics to position glyphs next to each other as
# a typesetting engine would, and renders them both by compositing a
# bitmap of each glyph onto the output image (using the bitmap_magick()
# convenience method) and by drawing the outline using MagickWand
# drawing functions.

# TODO - use kerning.

use Font::FreeType;
use Font::FreeType::BitMap;
use Font::FreeType::Face;
use MagickWand;
use MagickWand::Enums;
use NativeCall;

enum <x y>;

sub MAIN(Str $font-file, $output-image, Int :$size=72, Int :$dpi=600, Int :$border=23, Str :$text="\xC2g.", Bool :$shape ) {
    my Font::FreeType::Face $ft-face = Font::FreeType.face($font-file);
    $ft-face.set-char-size($size, 0, $dpi, $dpi);
    my @metrics = do if $shape {
        if (try require HarfBuzz::Font::FreeType) === Nil {
            die "HarfBuzz::Font::FreeType must be installed to use the --shape option";
        }
        require HarfBuzz::Shaper;
        my $font = HarfBuzz::Font::FreeType.new: :$ft-face, :size($size * 8.33) :features['kern'];
        my $shaper = HarfBuzz::Shaper.new: :$font, :buf{ :$text };
        $shaper.shape.map: -> $glyph {
            my $lb = $glyph.x-bearing;
            my $width =  $glyph.width;
            my $height =  $glyph.height;
            my $h-adv = $glyph.x-advance;
            my $rb = $h-adv - $width - $lb;
            %( :$lb, :$rb, :$h-adv);
        }
    }
    else {
        $ft-face.forall-chars: $text, {
            my $lb = .left-bearing;
            my $rb = .right-bearing;
            my $h-adv = .horizontal-advance;
            %( :$lb, :$rb, :$h-adv);
        }
    }

    # Work out how big the text will be.
    my $width   = $border * 2;
    my $*height = $border * 2 + $ft-face.height;
    if @metrics {
        $width += @metrics>>.<h-adv>.sum
               -  @metrics.head<lb>
               -  @metrics.tail<rb>;
    }
    
    $width .= round();
    $*height .= round();
    my MagickWand:D $img .= new;
    $img.create($width, $*height, 'white');
    $img.&set-stroke-color('#0000AA');

    my $origin-y = $border - $ft-face.descender;
    my ($*text-x, $*text-y) = ($border - @metrics.head<lb>, $origin-y);

    my $adj-base-y = adjust-position(0, 0)[y];
    my $adj-top-y = adjust-position(0, $ft-face.ascender)[y];
    my $adj-btm-y = adjust-position(0, $ft-face.descender)[y];

   given $img {
       .&set-stroke-color('#FF0000');
       .draw-line(0, $adj-base-y, $width, $adj-base-y);
       .&set-stroke-color('#00FF00');
       .draw-line(0, $adj-top-y, $width, $adj-top-y);
       .draw-line(0, $adj-btm-y, $width, $adj-btm-y);
   }

   $ft-face.forall-chars: $text, {
       my %metric = @metrics.shift;
       my ($adj-x, $adj-y) = adjust-position(0, 0);

       my Font::FreeType::BitMap $bm = .bitmap;
       my $bmp-left = $bm.left;
       my $bmp-top  = $bm.top;
       if $bmp-left && $bmp-top {
           my $buf = $bm.pgm;

           my MagickWand $bmp-img .= new;
           if $bmp-img.read-buffer(nativecast(Pointer, $buf), $buf.bytes) {
               $bmp-img.modulate(23, 0, 0);   # Light grey, not black.
               $img.composite(
                   $bmp-img,
                   DifferenceCompositeOp,
                   round($adj-x + $bmp-left),
               round($adj-y - $bmp-top),
               );
           }
           else {
               warn "unable to read image";
           }

           $img.&set-stroke-color('#CCCC00');

           do {
               my @*curr-pos = (0.0, 0.0);
               my Code %callbacks = (
                   move-to => sub {
                       @*curr-pos = adjust-position($^x, $^y);
                   },
                   line-to => sub {
                       my ($x, $y) = adjust-position($^_x, $^_y);
                       $img.draw-line(|@*curr-pos, $x, $y);
                       @*curr-pos = $x, $y;
                   },
                   cubic-to => sub {
                       my ($x, $y) = adjust-position($^_x, $^_y);
                       my ($cx1, $cy1) = adjust-position($^_cx1, $^_cy1);
                       my ($cx2, $cy2) = adjust-position($^_cx2, $^_cy2);
                       
                       $img.draw-line(|@*curr-pos, $x, $y); # stub
                       ##TODO           $img.&draw-bezier($cx1, $cy1, $cx2, $cy2, $x, $y);
                       @*curr-pos = ($x, $y);
                   },
               );
   
               .decompose :%callbacks;
           }
       }
       $img.draw-line($adj-x, 0,  $adj-x, $*height);
       $*text-x += %metric<h-adv>;
   }
   my $adj-x = adjust-position(0, 0)[x];
   $img.&set-stroke-color('#CCCC00');
   $img.draw-line($adj-x, 0,  $adj-x, $*height);
   $img.write($output-image);
}

# Y coordinates need to be flipped over, and both x and y adjusted to the
# position of the character.
sub set-stroke-color($img,$c) { $img.stroke($c); }
sub adjust-position($x, $y) {
    ($x + $*text-x,
     $*height - $y - $*text-y);
}



head

magic.raku - Demonstrate MagickWand rendering using Font::FreeType


magick.raku --text="Text" --shape font-file output-image


code

This Raku example script demonstrates `MagickWand` rendering of fonts using `Font::FreeType`.


`MagickWand` supports a wide range of image formats; which is determined from the extension of the output file.


The `--shape` option further demonstrates the use of `HarfBuzz` and `HarfBuzz::Font::FreeType` for glyph selection
and layout. These modules need to be installed prior to
using this option.


root

BBox

index

React

=begin React :component<HeaderCol> :id<menu> 
=para L<Documentation|/doc/introduction>
=para L<Modules| /mods>
=para L<Examples| file:../examples/index.podlite>
=para L<AI|file:../mcp/index.podlite>
=para L<Download |file:../download/index.podlite>
=para L<About|file:../about/index.podlite>
=para 🔍 K<⌘K>/K<ctrl-K>
=end React


=begin React :component<HeaderCol> :id<footer>  
=begin nested :!nested
=item1 B<Language>
    =item2 L<Get started|file:../getting-started/getting-started.podlite>
    =item2 L<Why Raku?|/doc/language/faq#Why-should-I-learn-Raku-What's-so-great-about-it>
    =item2 L<Try Raku|https://glot.io/new/raku>
    =item2 L<Download | file:../download/index.podlite>
    =item2 L<Raku cheat sheet|https://github.com/Raku/mu/blob/master/docs/Perl6/Cheatsheet/cheatsheet.txt>
    =item2 L<Raku on Exercism|https://exercism.org/tracks/raku>
    =item2 L<Wikipedia|https://en.wikipedia.org/wiki/Raku_(programming_language)>

=end nested
=begin nested :!nested

=item1 B<L<Documentation|/doc>>
    =item2 L<Getting started, Migration guides from other languages, & Tutorials | file:../doc/introduction.podlite>
    =item2 L<Language References|file:../doc/reference.podlite>
    =item2 L<Type Reference| file:../doc/types.podlite>
    =item2 L<Miscellaneous| file:../doc/miscellaneous.podlite>
    =item2 L<FAQs (Frequently Asked Questions)|/doc/language/faq>
    =item2 L<Community|/doc/language/community>
    =item2 L<The list of all documents|file:../doc/index.podlite>
    =item2 L<Hand these documents to an AI assistant|file:../mcp/index.podlite>

=end nested
=begin nested :!nested
=item1 B<Learning>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Wikibook |https://en.wikibooks.org/wiki/Raku_Programming>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>
    =item2 L<Learn Raku in Y minutes|https://learnxinyminutes.com/docs/raku/>
    =item2 L<Golfing |https://github.com/AlexDaniel/raku-golf-cheatsheet>
=end nested
=begin nested :!nested

=item1 B<Explore>
    =item2 L<Raku Blog Aggregator|https://planet.raku.org/>
    =item2 L<Rakudo Weekly|https://rakudoweekly.blog/>
    =item2 L<The Weekly Challenge |https://perlweeklychallenge.org/>
    =item2 L<Raku Advent Calendar|https://raku-advent.blog/>

=end nested
=end React


Built with L<Podlite|https://podlite.org> — the markup and publishing tools behind this site.


=begin React :component<CookieConsent> :id<CookieConsent> :buttonCaption("Got it!")
=para
This website uses cookies for analytics.
=end React


magick

Name

Synopsis

Example

Description

Font::FreeType v0.5.16

Authors

License

Dependencies

Test Dependencies

Provides

Documentation