unit module File::ExtendedAttributes;

use NativeCall;
use Unix::errno;

class X::File::ExtendedAttributes::Unsupported is Exception {
    method message() {
        "Extended attributes are unsupported on this filesystem"
    }
}

sub handle-error {
    my $err = errno();
    die X::File::ExtendedAttributes::Unsupported.new if $err ~~ /'not supported'/;
    die $err;
}

sub listxattr(Str $path, CArray[uint8] $list, size_t $size) returns ssize_t is native {*}

our sub list-attributes(Str() $path) is export {
    my $size = listxattr($path, Any, 0);
    handle-error() if $size < 0;

    my $out = CArray[uint8].allocate($size);
    my $read = listxattr($path, $out, $size);
    handle-error() if $read < 0;

    # attributes are returned as a NULL separated list
    return Buf.new($out.list).decode.split("\0", :skip-empty);
}

sub getxattr(Str $path, Str $key, CArray[uint8] $value, size_t $size) returns size_t is native {*}

our sub get-attribute(Str() $path, Str $key, Bool :$bin) is export {
    my $size = getxattr($path, $key, Any, 0);
    handle-error() if $size < 0;

    my $out = CArray[uint8].allocate($size);
    my $read = getxattr($path, $key, $out, $size);
    handle-error() if $read < 0;

    my $data = Blob[uint8].new($out.list);
    return $data if $bin;
    return $data.decode;
}

sub setxattr_blob(Str $path, Str $key, CArray[uint8] $value, size_t $size, int32 $flags) returns int32 is native is symbol('setxattr') {*}
sub setxattr_str(Str $path, Str $key, Str $value, size_t $size, int32 $flags) returns int32 is native is symbol('setxattr') {*}

our proto set-attribute(Str() $path, Str $key, $value) is export {*}
multi sub set-attribute(Str() $path, Str $key, Str $value) {
    my $rv = setxattr_str($path, $key, $value, $value.encode.bytes, 0);
    handle-error() if $rv < 0;
}

multi sub set-attribute(Str() $path, Str $key, Blob[uint8] $value) {
    my $in = CArray[uint8].new: $value;
    my $rv = setxattr_blob($path, $key, $in, $value.elems, 0);
    handle-error() if $rv < 0;
}

sub removexattr(Str $path, Str $key) returns int32 is native {*}

our sub remove-attribute(Str() $path, Str $key) is export {
    my $rv = removexattr($path, $key);
    handle-error() if $rv < 0;
}



head

File::ExtendedAttributes - access extended attributes of files


code

=begin code :lang<raku>

use File::ExtendedAttributes;

say list-attributes($path);

set-attribute($path, "user.test", "hello world");

say get-attribute($path, "user.test"); # as a str
say get-attribute($path, "user.test", :bin); # as a blob

remove-attribute($path, "user.test");

=end code


File::ExtendedAttributes is a module to provide low-level access to extended attributes on Linux, sometimes known as C<xattr>s. These attributes are used for various metadata stored outside the file itself that can be interpreted by one or more applications.


This feature is well-supported on typical Linux filesystems, but may not be supported in all cases, especially with networked filesystems. Many filesystems generally impose size limits of a single filesystem block (often 1024, 2048, or 4096 bytes), so be frugal with the size of this metadata.


These attributes are conceptually key/value pairs. In Linux, the C<key> must begin with a namespace (typically C<user>) and a period, such as C<"user.test">. The value is an arbitrary string or blob.


Returns a list of attributes defined on the given path.


Returns the value of the attribute if present. This value will be decoded as utf-8, unless the C<:bin> parameter is specified.


Sets the specified attribute to the provided value. C<$value> may be a C<Str> or a C<Blob[uint8]>. If C<$value> is a string, it is encoded in utf-8 before being stored.


Removes the given attribute. If the specified attribute does not exist, then an error is thrown (errno is C<ENODATA>).


If an error occurs, C<die> is called with the error message (provided by C<errno>). Error reporting may not be reliable if another thread can overwrite C<errno>.


The commands C<getfattr>/C<setfattr> and C<attr>


This library is free software; you can redistribute it and/or modify it under the Artistic License 2.0.


root

README

React

=begin React :component<HeaderCol> :id<menu> 
=para L<Documentation|/doc/introduction>
=para L<Modules| /mods>
=para L<Examples| file:../examples/index.podlite>
=para L<Download |file:../download/index.podlite>
=para L<About|file:../about/index.podlite>
=para 🔍 K<⌘K>/K<ctrl-K>
=end React


=begin React :component<HeaderCol> :id<footer>  
=begin nested :!nested
=item1 B<Language>
    =item2 L<Get started|file:../getting-started/getting-started.podlite>
    =item2 L<Why Raku?|/doc/language/faq#Why-should-I-learn-Raku-What's-so-great-about-it>
    =item2 L<Try Raku|https://glot.io/new/raku>
    =item2 L<Raku cheat sheet|https://github.com/Raku/mu/blob/master/docs/Perl6/Cheatsheet/cheatsheet.txt>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<Raku on Exercism|https://exercism.org/tracks/raku>
    =item2 L<Wikipedia|https://en.wikipedia.org/wiki/Raku_(programming_language)>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=end nested
=begin nested :!nested

=item1 B<L<Documentation|/doc>>
    =item2 L<Getting started, Migration guides from other languages, & Tutorials | file:../doc/introduction.podlite>
    =item2 L<Language References|file:../doc/reference.podlite>
    =item2 L<Type Reference| file:../doc/types.podlite>
    =item2 L<Miscellaneous| file:../doc/miscellaneous.podlite>
    =item2 L<FAQs (Frequently Asked Questions)|/doc/language/faq>
    =item2 L<Community|/doc/language/community>
    =item2 L<The list of all documents|file:../doc/index.podlite>

=item1 B<Resources>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>

=end nested
=begin nested :!nested

=item1 B<Resoures>
    =item2 L<Download | file:../download/index.podlite>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=item1 B<Learning>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Wikibook |https://en.wikibooks.org/wiki/Raku_Programming>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>
    =item2 L<Learn Raku in Y minutes|https://learnxinyminutes.com/docs/raku/>
    =item2 L<Golfing |https://github.com/AlexDaniel/raku-golf-cheatsheet>
=end nested
=begin nested :!nested

=item1 B<Explore>
    =item2 L<Raku Blog Aggregator|https://planet.raku.org/>
    =item2 L<Rakudo Weekly|https://rakudoweekly.blog/>
    =item2 L<The Weekly Challenge |https://perlweeklychallenge.org/>
    =item2 L<Raku Advent Calendar|https://raku-advent.blog/>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=end nested
=end React


=begin React :component<CookieConsent> :id<CookieConsent> :buttonCaption("Got it!")
=para
This website uses cookies for analytics.
=end React


ExtendedAttributes

NAME

SYNOPSIS

DESCRIPTION

FUNCTIONS

list-attributes($path)

get-attribute($path, $key, :$bin)

set-attribute($path, $key, $value)

remove-attribute($path, $key)

ERRORS

SEE ALSO

AUTHOR

COPYRIGHT AND LICENSE

File::ExtendedAttributes v0.0.1

Authors

License

Dependencies

Test Dependencies

Provides

Documentation