Image

head

code

root

para

L<Examples| file:../examples/index.podlite>


L<Download |file:../download/index.podlite>


React

=begin React :component<HeaderCol> :id<menu> 
=para L<Documentation|/doc/introduction>
=para L<Modules| /mods>
=para L<Examples| file:../examples/index.podlite>
=para L<Download |file:../download/index.podlite>
=para L<About|file:../about/index.podlite>
=para 🔍 K<⌘K>/K<ctrl-K>
=end React


HEADER

FOOTER

README

unit class App::Lorea::Command:ver<0.2.2>;

use Terminal::ANSIColor;
constant RAINBOW = < red green yellow blue magenta cyan >;

my role Queue {
    method add  ( Str )             { ... }
    method take (     ) returns Str { ... }
}

my class Backlog does Queue {
    has SetHash $!queue;
    method add  ( Str $s where *.chars > 0 ) { $!queue{$s} = True }
    method take ( --> Str ) { $!queue ?? $!queue.grab !! '' }
}

my class Task does Queue {
    has Str $!task;
    method add  ( Str $s where *.chars > 0 ) { $!task = $s }
    method take ( --> Str ) {
        LEAVE $!task = '';
        return $!task;
    }
}

my $id = 0;
has Int $!id = $id++;

has Str         @!args       is built;
has Str         $!substitute is built;
has Supply      $!supply     is built;
has Bool        $!is-service is built;
has Bool        $!colours    is built;
has Bool        $!numbers    is built;
has Queue       $!queue;
has Proc::Async $!proc;
has Promise     $!done;
has &!decorator = sub ( $out, $msg ) { $out.say: $msg.chomp }

method new ( $args, *%extra ) {
    self.bless: args => $args.flat, |%extra;
}

method TWEAK () {
    $!queue = $!is-service.not || @!args (&) $!substitute
        ?? Backlog.new !! Task.new;

    &!decorator.wrap: -> $out, $msg {
        $out.&callwith( colored $msg.chomp, 'bold ' ~ RAINBOW[$!id + 1 % *] )
    } if $!colours;

    &!decorator.wrap: -> $out, $msg {
        $out.&callwith( sprintf '[%02d] %s', $!id, $msg )
    } if $!numbers;

    self!start if $!is-service;
}

method !say  ($msg) { &!decorator($*OUT, $msg) }
method !note ($msg) { &!decorator($*ERR, $msg) }

my Lock $sequential-lock;
method make-sequential { $sequential-lock ||= Lock.new }

method !start ( :$path --> Promise) {
    if try $!done.status ~~ Planned {
        # self!note: 'Command is already started and still running';
        return $!done
    }

    my @args = @!args;
    @args .= map: *.subst: $!substitute, $path if $path;

    $!proc .= new: @args;

    $!proc.stdout.tap: &!decorator.assuming($*OUT);
    $!proc.stderr.tap: &!decorator.assuming($*ERR);

    .lock with $sequential-lock;

    self!say('Starting service') if $!is-service;

    $!done = $!proc.start;
    $!done.then: { self!note('Service has finished') } if $!is-service;

    await $!done and .unlock with $sequential-lock;
    $!done;
}

method !restart ( :$path --> Promise ) {
    use Timer::Breakable;
    # note 'In restart';

    if try $!done.status ~~ Planned {
        &!decorator($*ERR, 'Killing service') if $!is-service;
        $!proc.kill: SIGTERM;

        my $timeout = Timer::Breakable.start: 1, {
            # Not working for now.
            # See https://github.com/rakudo/rakudo/issues/1701
            self!note: 'Process did not finish on time! Trying harder';
            $!proc.kill: SIGKILL;
        }

        await $!done.clone.then: { $timeout.stop }
    }

    self!start: :$path;
}

method !process-queue () {
    while $!queue.take -> $path {
        # note 'Restarting for ' ~ $path;
        await self!restart: :$path;

        CATCH {
            when X::Proc::Unsuccessful {
                when quietly .proc.signal == 9|15 {
                    # Process was terminated, likely by us. Nothing to see here
                }
            }
            default {
                my @args = @!args.map: *.subst: $!substitute, $path;
                self!note: "Encountered an error when running '{ @args.join: ' ' }";
                self!note: .message;
            }
        }
    }
}

method run ( --> Promise ) {
    use Timer::Stopwatch;
    my Timer::Stopwatch $timer .= new;

    start react {
        whenever $!supply {
            # True if we are still within the window
            $timer.reset: 0.3;
            $!queue.add: .path;
        }
        whenever $timer { start self!process-queue }
    }
}



App::Lorea::Command - A class representing a command to be run by lorea


=begin code

use App::Lorea::Watcher;
use App::Lorea::Command;

my $supply = $path.&watch-recursive(
    debounce => 0.5,
    exclude  => rx{ '~' $ }, # Ignore files ending in ~
);

.run with App::Lorea::Command.new: @args, :$is-service, :$supply;

=end code


This module represents a command to be executed by the C<lorea> command line
client. It makes little sense to use it outside of that context.


A C<List> of arguments to pass to the underlying process.


A C<Bool> to specify if this command is a service or not. A service is a
command that is expected to be constantly running, and restarted on a
file-system change. The alternative is a command that is most normally
short-running, and is started on a file-system change.


A C<Supply> of C<IO::Notification::Change> objects. After calling C<run>,
every string received sent to this C<Supply> will trigger be enqueued to
trigger a possible command restart.


See C<run> for an explanation of the queueing process.


=begin code
method run returns Promise
=end code


Start listening to events from the C<Supply> passed to the constructor.
Every event is expected to be a C<IO::Notification::Change>. File-system
changes will be queued and the queue will be processed after a 300
milliseconds have ellapsed since the last event.


How these queues work depends on whether this command represents a
"service" or not.


Queues for services only keep the last event that has come in. This means
that a set of events rapidly firing with less that 300 milliseconds between
each will trigger a single service restart.


Queues for non-service commands keep unique events, which are processed
in an unspecified order.


This library is free software; you can redistribute it and/or modify it
under the Artistic License 2.0.


Command

item

pages

The Raku Knowledge Base


=begin React :component<HeaderCol> :id<footer>  
=begin nested :!nested
=item1 B<Language>
    =item2 L<Get started|file:../getting-started/getting-started.podlite>
    =item2 L<Why Raku?|/doc/language/faq#Why-should-I-learn-Raku-What's-so-great-about-it>
    =item2 L<Try Raku|https://glot.io/new/raku>
    =item2 L<Raku cheat sheet|https://github.com/Raku/mu/blob/master/docs/Perl6/Cheatsheet/cheatsheet.txt>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<Raku on Exercism|https://exercism.org/tracks/raku>
    =item2 L<Wikipedia|https://en.wikipedia.org/wiki/Raku_(programming_language)>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=end nested
=begin nested :!nested

=item1 B<L<Documentation|/doc>>
    =item2 L<Getting started, Migration guides from other languages, & Tutorials | file:../doc/introduction.podlite>
    =item2 L<Language References|file:../doc/reference.podlite>
    =item2 L<Type Reference| file:../doc/types.podlite>
    =item2 L<Miscellaneous| file:../doc/miscellaneous.podlite>
    =item2 L<FAQs (Frequently Asked Questions)|/doc/language/faq>
    =item2 L<Community|/doc/language/community>
    =item2 L<The list of all documents|file:../doc/index.podlite>

=item1 B<Resources>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>

=end nested
=begin nested :!nested

=item1 B<Resoures>
    =item2 L<Download | file:../download/index.podlite>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=item1 B<Learning>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Wikibook |https://en.wikibooks.org/wiki/Raku_Programming>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>
    =item2 L<Learn Raku in Y minutes|https://learnxinyminutes.com/docs/raku/>
    =item2 L<Golfing |https://github.com/AlexDaniel/raku-golf-cheatsheet>
=end nested
=begin nested :!nested

=item1 B<Explore>
    =item2 L<Raku Blog Aggregator|https://planet.raku.org/>
    =item2 L<Rakudo Weekly|https://rakudoweekly.blog/>
    =item2 L<The Weekly Challenge |https://perlweeklychallenge.org/>
    =item2 L<Raku Advent Calendar|https://raku-advent.blog/>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=end nested
=end React


=begin React :component<CookieConsent> :id<CookieConsent> :buttonCaption("Got it!")
=para
This website uses cookies for analytics.
=end React


README

NAME

SYNOPSIS

DESCRIPTION

AUTHOR

COPYRIGHT AND LICENSE

App::IRC::Log v0.0.24

Authors

License

Dependencies

Test Dependencies

Provides

Documentation