para

use v6.c;

use WebService::FootballData;
use Text::Table::Simple;

unit class App::Football:ver(v0.1.3);

my $.program_name = 'football';

has $.fd = WebService::FootballData.new;

method team ($team_name) {
    my $team = $!fd.team: $team_name;

    self!not_found: 'Team' unless $team;

    self!print_teams: $team;

    $team;
}

method team_players ($team_name) {
    my $team = self.team: $team_name;
    my $players = $team.players;

    self!not_found: 'Players' unless $players;

    my @cols = <# Player Position Age Birthdate Nationality Contract Value>;
    my @rows = $players.map: {
        my $contract_year = .year with .contract_date;
        my $birth_date = .Str with .birth_date;

        .number, .name, .position, .age, $birth_date, .nationality, $contract_year, .market_value
    }

    self!print_table: @cols, @rows;
}

method team_fixtures ($team_name, :$season, :$timeframe, :$venue) {
    my $team = self.team: $team_name;
    my $fixtures = $team.fixtures: :$season, :$timeframe, :$venue;

    self!not_found: 'Fixtures' unless $fixtures;

    self!print_fixtures: $fixtures;
}

method leagues (:$season) {
    my $leagues = $!fd.leagues: :$season;

    self!print_leagues: $leagues.sort: *.name;
}

method league ($league_name, :$season) {
    my $league = $!fd.league: $league_name, :$season;

    self!not_found: 'League' unless $league;

    self!print_leagues: $league;

    $league;
}

method league_teams ($league_name, :$season) {
    my $league = self.league: $league_name, :$season;

    my $teams = $league.teams;

    self!not_found: 'Teams' unless $teams;

    self!print_teams: $teams.sort: *.name;
}

method league_table ($league_name, :$season, :$matchday) {
    my $league = self.league: $league_name, :$season;

    say "Matchday $_" with $matchday;

    my $league_table = $league.table($matchday).rows;

    self!not_found: 'Table' unless $league_table;

    my @cols = <Pos Team Pts Pld GF GA GD W D L HW HD HL AW AD AL>;
    my @rows = $league_table.map: {
        .position, .name, .points, .games_played, .goals_for, .goals_against, .goal_difference,
        .wins, .draws, .losses, .home.wins, .home.draws, .home.losses, .away.wins, .away.draws, .away.losses
    };

    self!print_table: @cols, @rows;
}

method league_fixtures ($league_name, :$season, :$matchday, :$timeframe) {
    my $league = self.league: $league_name, :$season;

    say "Matchday $_" with $matchday;

    my $fixtures = $league.fixtures: :$matchday, :$timeframe;

    self!not_found: 'Fixtures' unless $fixtures;

    self!print_fixtures: $fixtures;
}

method all_fixtures (:$timeframe, :$league-code) {
    my Str $league = .uc with $league-code;

    my $fixtures = $!fd.all_fixtures(:$timeframe, :$league).fixtures;

    self!not_found: 'Fixtures' unless $fixtures;

    self!print_fixtures: $fixtures;
}

method !print_teams ($teams) {
    my @cols = «Team 'Short Name' Code 'Squad Value'»;
    my @rows = $teams.map: { .name, .short_name, .code, .squad_market_value };

    self!print_table: @cols, @rows;
}

method !print_leagues ($leagues) {
    my @cols = <League Code Season Matchday Matchdays Teams Games>;
    my @rows = $leagues.map: { .name, .code, .season, .current_matchday, .number_of_matchdays, .number_of_teams, .number_of_games };

    self!print_table: @cols, @rows;
}

method !print_fixtures (@fixtures) {
    my @cols = «Day 'Home Team' HG AG 'Away Team' Status 'Date & Time'»;
    my @rows = @fixtures.map: {
        my $date = self!format_date: .local with .date;

        .matchday, .home_team_name, .result.home_team_goals,
        .result.away_team_goals, .away_team_name,
        .status, $date
    }

    self!print_table: @cols, @rows;
}

method !print_table (@cols, @rows) {
    say lol2table(@cols, @rows).join: "\n";
}

method !format_date (DateTime $date_time) returns Str {
    sprintf '%s %02d:%02d', .yyyy-mm-dd, .hour, .minute given $date_time;
}

method !not_found (Str $resource) {
    "{self.program_name}: $resource not found".note and exit;
}



head

App::Football - Contains methods for football program


code

=begin code

use App::Football;

# Print football leagues
App::Football.new.leagues;

=end code


Class used by football script. It's not intended to be used by users.


A class attribute containing the program name.


An instance of C<WebService::FootballData>.


Prints team's data and a list of its players and their data.


item

Prints team's data and a list of its fixtures and their data.


Prints a list of leagues and their data.


Prints league's data and a list of its teams and their data.


Prints league's data and a list of its fixtures and their data.


root

README

React

=begin React :component<HeaderCol> :id<menu> 
=para L<Documentation|/doc/introduction>
=para L<Modules| /mods>
=para L<Examples| file:../examples/index.podlite>
=para L<AI|file:../mcp/index.podlite>
=para L<Download |file:../download/index.podlite>
=para L<About|file:../about/index.podlite>
=para 🔍 K<⌘K>/K<ctrl-K>
=end React


=begin React :component<HeaderCol> :id<footer>  
=begin nested :!nested
=item1 B<Language>
    =item2 L<Get started|file:../getting-started/getting-started.podlite>
    =item2 L<Why Raku?|/doc/language/faq#Why-should-I-learn-Raku-What's-so-great-about-it>
    =item2 L<Try Raku|https://glot.io/new/raku>
    =item2 L<Download | file:../download/index.podlite>
    =item2 L<Raku cheat sheet|https://github.com/Raku/mu/blob/master/docs/Perl6/Cheatsheet/cheatsheet.txt>
    =item2 L<Raku on Exercism|https://exercism.org/tracks/raku>
    =item2 L<Wikipedia|https://en.wikipedia.org/wiki/Raku_(programming_language)>

=end nested
=begin nested :!nested

=item1 B<L<Documentation|/doc>>
    =item2 L<Getting started, Migration guides from other languages, & Tutorials | file:../doc/introduction.podlite>
    =item2 L<Language References|file:../doc/reference.podlite>
    =item2 L<Type Reference| file:../doc/types.podlite>
    =item2 L<Miscellaneous| file:../doc/miscellaneous.podlite>
    =item2 L<FAQs (Frequently Asked Questions)|/doc/language/faq>
    =item2 L<Community|/doc/language/community>
    =item2 L<The list of all documents|file:../doc/index.podlite>
    =item2 L<Hand these documents to an AI assistant|file:../mcp/index.podlite>

=end nested
=begin nested :!nested
=item1 B<Learning>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Wikibook |https://en.wikibooks.org/wiki/Raku_Programming>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>
    =item2 L<Learn Raku in Y minutes|https://learnxinyminutes.com/docs/raku/>
    =item2 L<Golfing |https://github.com/AlexDaniel/raku-golf-cheatsheet>
=end nested
=begin nested :!nested

=item1 B<Explore>
    =item2 L<Raku Blog Aggregator|https://planet.raku.org/>
    =item2 L<Rakudo Weekly|https://rakudoweekly.blog/>
    =item2 L<The Weekly Challenge |https://perlweeklychallenge.org/>
    =item2 L<Raku Advent Calendar|https://raku-advent.blog/>

=end nested
=end React


Built with L<Podlite|https://podlite.org> — the markup and publishing tools behind this site.


=begin React :component<CookieConsent> :id<CookieConsent> :buttonCaption("Got it!")
=para
This website uses cookies for analytics.
=end React


Football

NAME

SYNOPSIS

DESCRIPTION

ATTRIBUTES

program_name

fd

METHODS

team

team_players

team_fixtures

leagues

league

league_teams

league_table

league_fixtures

all_fixtures

AUTHOR

COPYRIGHT AND LICENSE