Image

head

code

root

para

L<Examples| file:../examples/index.podlite>


L<Download |file:../download/index.podlite>


React

=begin React :component<HeaderCol> :id<menu> 
=para L<Documentation|/doc/introduction>
=para L<Modules| /mods>
=para L<Examples| file:../examples/index.podlite>
=para L<Download |file:../download/index.podlite>
=para L<About|file:../about/index.podlite>
=para 🔍 K<⌘K>/K<ctrl-K>
=end React


HEADER

FOOTER

README

item

01-basics

use IRC::Client;

class IRC::Client::Plugin::Logger:ver<0.0.4>:auth<zef:lizmat> {
    has IO()  $.directory is required;
    has Int() $.debug        = 0;
    has       &!now is built = { DateTime.now.utc };
    has       %!channels;  # %!channels<nick><channel> = 1

    my constant Join    = IRC::Client::Message::Join;
    my constant Message = IRC::Client::Message::Privmsg::Channel;
    my constant Mode    = IRC::Client::Message::Mode::Channel;
    my constant Nick    = IRC::Client::Message::Nick;
    my constant Numeric = IRC::Client::Message::Numeric;
    my constant Part    = IRC::Client::Message::Part;
    my constant Topic   = IRC::Client::Message::Topic;
    my constant Quit    = IRC::Client::Message::Quit;

    method log(Str:D $channel, Str:D $text) {
        my $now := &!now();
        my $dir := $!directory.add($channel.substr(1)).add($now.year);
        $dir.mkdir unless $dir.e;

        $dir.add($now.yyyy-mm-dd).spurt:
          "&sprintf("[%02d:%02d]", $now.hour, $now.minute) $text\n",
          :append;
    }

    method !debug($event --> Nil) {
        if $!debug > 1 {
            if $event.?channel -> $channel {
                note "$channel: $event";
            }
            else {
                note $event;
            }
        }
    }

    method irc-to-me($event) {
        $event.reply:
          "Logging {$event.channel} with Raku module {self.^name} {self.^ver}";
    }

    proto method irc-all($event) {
        note $event.^name if $!debug;
        {*}
    }

    multi method irc-all(Join:D $event --> Nil) {
        my $nick := $event.nick;

        if $nick eq $event.server.current-nick {
            self!debug($event) if $!debug;
        }
        else {
            my $channel := $event.channel;
            self.log: $channel, "*** $nick joined";
            %!channels{$nick}{$channel} := 1;
        }
    }

    multi method irc-all(Message:D $event --> Nil) {
        my $text := $event.text;
        self.log(
          $event.channel,
          $text.substr-eq("ACTION ",1)
            ?? "* $event.nick() $event.text.substr(8,*-1)\n"
            !! "<$event.nick()> $event.text()\n"
        ) unless $text.starts-with('[off]');
    }

    multi method irc-all(Mode:D $event --> Nil) {
        self.log:
          $event.channel,
          "*** $event.nick() sets mode: $event.mode() $event.nicks()\n";
    }

    multi method irc-all(Nick:D $event --> Nil) {
        my $old-nick := $event.nick;
        my $new-nick := $event.new-nick;

        self.log: $_, "*** $old-nick is now known as $new-nick\n"
          for %!channels{$old-nick}.keys;

        %!channels{$new-nick} = %!channels{$old-nick}:delete;
    }

    multi method irc-all(Numeric:D $event --> Nil) {
        if $event.command == 353 {   # listing nicks on channels
            my $channel := $event.args[2];
            %!channels{$_}{$channel} := 1 for $event.args[3].words;
        }
        else {
            self!debug($event);
        }
    }

    multi method irc-all(Part:D $event --> Nil) {
        my $nick    := $event.nick;
        my $channel := $event.channel;
        self.log: $channel, "*** $nick left";
        %!channels{$nick}{$channel}:delete;
    }

    multi method irc-all(Quit:D $event --> Nil) {
        my $nick := $event.nick;

        if %!channels{$nick}:delete -> $channels {
            self.log: $_, "*** $nick left" for $channels.keys;
        }
    }

    multi method irc-all(Topic:D $event --> Nil) {
        self.log:
          $event.channel,
          "*** $event.nick() changes topic to: $event.text()";
    }

    multi method irc-all($event --> Nil) {
        self!debug($event);
    }
}



IRC::Client::Plugin::Logger - IRC logger for historic purposes


=begin code :lang<raku>

use IRC::Client;
use IRC::Client::Plugin::Logger;

.run with IRC::Client.new(
  :nick<SomeBot>,
  :host<irc.freenode.org>,
  :channels<#channel1 #channel2>,
  :plugins(IRC::Client::Plugin::Logger.new(:directory<logs>,:debug)),
)

=end code


IRC::Client::Plugin::Logger exports a class that is to be used as a
plugin of the L<IRC::Client> framework.


It is a simple IRC logger for C<historical> purposes, so B<not> for
forensic logging.  As such, it does B<not> keep IP number information,
user names nor exact timestamps.


It produces logs compatible with the "raw" format of the colabti.org
IRC logger, which contains hh::mm timestamps, join / leave / nick
notices and messages sent to the channel.  It will not log messages
that start with '[off]'.


The directory in which the logs should be placed.  It should be writable
by the process that runs the C<IRC::Client>.


A numeric value to indicate debug level.  If it is non-zero, it will
produce debugging output on STDERR.


A C<Callable> that should return a C<DateTime> object to be used to
determine date and time an event should be logged.  Defaults to the
current time in UTC.  Mostly intended for testing purposes to get a
reproducible logging result, but can also be used to e.g. have times
logged in local time.


From the given directory, a directory will be made for each channel
(excluding the C<#> prefix).  Inside it, a directory will be made for
each year in which messages are logged.  Inside that, a file will be
made for each day that messages are logged, with the name of the
format `YYYY-MM-DD`.


So, for logging the #raku channel on 22 April 2021 with a directory
setting of C<~/logs>, you will get:


Source can be located at: https://github.com/lizmat/IRC-Client-Plugin-Logger .
Comments and Pull Requests are welcome.


This library is free software; you can redistribute it and/or modify it under the Artistic License 2.0.


Logger

The Raku Knowledge Base


=begin React :component<HeaderCol> :id<footer>  
=begin nested :!nested
=item1 B<Language>
    =item2 L<Get started|file:../getting-started/getting-started.podlite>
    =item2 L<Why Raku?|/doc/language/faq#Why-should-I-learn-Raku-What's-so-great-about-it>
    =item2 L<Try Raku|https://glot.io/new/raku>
    =item2 L<Raku cheat sheet|https://github.com/Raku/mu/blob/master/docs/Perl6/Cheatsheet/cheatsheet.txt>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<Raku on Exercism|https://exercism.org/tracks/raku>
    =item2 L<Wikipedia|https://en.wikipedia.org/wiki/Raku_(programming_language)>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=end nested
=begin nested :!nested

=item1 B<L<Documentation|/doc>>
    =item2 L<Getting started, Migration guides from other languages, & Tutorials | file:../doc/introduction.podlite>
    =item2 L<Language References|file:../doc/reference.podlite>
    =item2 L<Type Reference| file:../doc/types.podlite>
    =item2 L<Miscellaneous| file:../doc/miscellaneous.podlite>
    =item2 L<FAQs (Frequently Asked Questions)|/doc/language/faq>
    =item2 L<Community|/doc/language/community>
    =item2 L<The list of all documents|file:../doc/index.podlite>

=item1 B<Resources>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>

=end nested
=begin nested :!nested

=item1 B<Resoures>
    =item2 L<Download | file:../download/index.podlite>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=item1 B<Learning>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Wikibook |https://en.wikibooks.org/wiki/Raku_Programming>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>
    =item2 L<Learn Raku in Y minutes|https://learnxinyminutes.com/docs/raku/>
    =item2 L<Golfing |https://github.com/AlexDaniel/raku-golf-cheatsheet>
=end nested
=begin nested :!nested

=item1 B<Explore>
    =item2 L<Raku Blog Aggregator|https://planet.raku.org/>
    =item2 L<Rakudo Weekly|https://rakudoweekly.blog/>
    =item2 L<The Weekly Challenge |https://perlweeklychallenge.org/>
    =item2 L<Raku Advent Calendar|https://raku-advent.blog/>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=end nested
=end React


=begin React :component<CookieConsent> :id<CookieConsent> :buttonCaption("Got it!")
=para
This website uses cookies for analytics.
=end React


README

NAME

SYNOPSIS

DESCRIPTION

PARAMETERS

directory

debug

now

DIRECTORY STRUCTURE

AUTHOR

COPYRIGHT AND LICENSE

IRC::Client::Plugin::Logger v0.0.4

Authors

License

Dependencies

Test Dependencies

Provides

Documentation