Image

head

code

root

para

L<Examples| file:../examples/index.podlite>


L<Download |file:../download/index.podlite>


React

=begin React :component<HeaderCol> :id<menu> 
=para L<Documentation|/doc/introduction>
=para L<Modules| /mods>
=para L<Examples| file:../examples/index.podlite>
=para L<Download |file:../download/index.podlite>
=para L<About|file:../about/index.podlite>
=para 🔍 K<⌘K>/K<ctrl-K>
=end React


HEADER

FOOTER

README

use v6.d;

module Hash::Restricted:ver<0.0.7>:auth<zef:lizmat> {

    sub nono($what, \map, \keys) is hidden-from-backtrace {
        die "Not allowed to $what {map.VAR.name}<{keys}>";
    }

    # The role to be applied if not a specific set of keys was given.
    # This will set the allowable keys after the first initialization.
    my role restrict-current {
        has %!allowed;

        method AT-KEY(::?CLASS:D: \key) is hidden-from-backtrace {
            %!allowed.EXISTS-KEY(key)
              ?? (nextsame)
              !! nono("access non-existing",self,key)
        }
        method ASSIGN-KEY(::?CLASS:D: \key, \value) is hidden-from-backtrace {
            %!allowed.EXISTS-KEY(key)
              ?? (nextsame)
              !! nono("create",self,key)
        }
        method BIND-KEY(::?CLASS:D: \key, \value) is hidden-from-backtrace {
            %!allowed.EXISTS-KEY(key)
              ?? (nextsame)
              !! nono("create",self,key)
        }
        method STORE(
          \to_store, :initialize(:$INITIALIZE)
        ) is hidden-from-backtrace {
            callsame;
            if $INITIALIZE {
                %!allowed = self.keys.map: * => True;
            }
            else {
                if self (-) %!allowed -> $extra {
                    self{$extra.keys}:delete;
                    nono("store",self,$extra.keys)
                }
            }
            self
        }
    }

    # The role to be applied with a given set of keys.
    my role restrict-given[%allowed] {
        method AT-KEY(::?CLASS:D: \key) is hidden-from-backtrace {
            %allowed.EXISTS-KEY(key)
              ?? (nextsame)
              !! nono("access non-existing",self,key)
        }
        method ASSIGN-KEY(::?CLASS:D: \key, \value) is hidden-from-backtrace {
            %allowed.EXISTS-KEY(key)
              ?? (nextsame)
              !! nono("create",self,key)
        }
        method BIND-KEY(::?CLASS:D: \key, \value) is hidden-from-backtrace {
            %allowed.EXISTS-KEY(key)
              ?? (nextsame)
              !! nono("create",self,key)
        }
        method STORE(\to_store) is hidden-from-backtrace {
            callsame;
            if self (-) %allowed -> $extra {
                self{$extra.keys}:delete;
                nono("store",self,$extra.keys)
            }
            self
        }
    }

    # Handle the "is restricted" / is restricted(Bool:D) cases
    multi sub trait_mod:<is>(Variable:D \v, Bool:D :$restricted!) is export {
        die "Can only apply 'is restricted' on a Map, not a {v.var.WHAT}"
          unless v.var.WHAT ~~ Map;
        my $name = v.var.^name;
        if $restricted {
            trait_mod:<does>(v, restrict-current);
            v.var.WHAT.^set_name("$name\(restricted)");
        }
    }

    # Handle the "is restricted<a b c>" case
    multi sub trait_mod:<is>(Variable:D \v, :@restricted!) is export {
        die "Can only apply 'is restricted' on a Map, not a {v.var.WHAT}"
          unless v.var.WHAT ~~ Map;
        my %restricted = @restricted.map: * => True;
        my $name = v.var.^name;
        trait_mod:<does>(v, restrict-given[%restricted]);
        v.var.WHAT.^set_name("$name\(restricted)");
    }
}



Hash::Restricted - trait for restricting keys in hashes


my %h is restricted = a => 42, b => 666;
%h<c> = 317;  # dies


my %h is restricted<a b>;
%h<a> = 42;
%h<b> = 666;
%h<c> = 317;  # dies


Hash::Restricted provides a C<is restricted> trait on C<Map>s and C<Hash>es
as an easy way to restrict which keys are going to be allowed in the C<Map> /
C<Hash>.


If you do not specify any keys with C<is restricted>, it will limit to the
keys that were specified when the C<Map> / C<Hash> was initialized.


If you B<do> specify keys, then those will be the keys that will be allowed.


Source can be located at: https://github.com/lizmat/Hash-Restricted .
Comments and Pull Requests are welcome.


This library is free software; you can redistribute it and/or modify it under the Artistic License 2.0.


Restricted

use v6.c;

use Hash::Agnostic:ver<0.0.10>:auth<zef:lizmat>;

role Hash::Ordered:ver<0.0.2>:auth<zef:lizmat>
  does Hash::Agnostic
{
    has %!indices;
    has str @.keys;
    has Mu  @.values;

    method AT-KEY(::?ROLE:D: \key) is raw {
        Proxy.new(
            FETCH => {
                with %!indices.AT-KEY(key) {
                    @!values.AT-POS($_)
                }
                else { Nil }
            },
            STORE => -> $, \value {
                with %!indices.AT-KEY(key) {
                    @!values.ASSIGN-POS($_, value)
                }
                else {
                    my int $index = @!keys.elems;
                    @!keys.ASSIGN-POS($index, key);
                    %!indices.BIND-KEY(key, $index);
                    @!values.ASSIGN-POS($index, value)
                }
            }
        )
    }

    method BIND-KEY(::?ROLE:D: \key, \value) is raw {
        with %!indices.AT-KEY(key) -> \index {
            @!values.BIND-POS(index, value)
        }
        else {
            my int $index = @!keys.elems;
            @!keys.ASSIGN-POS($index, key);
            @!values.BIND-POS($index, value);
            %!indices.BIND-KEY(key, $index);
        }
    }

    method CLEAR(::?ROLE:D:) {
        %!indices = @!keys = @!values = Empty;
    }

    method DELETE-KEY(::?ROLE:D: \key) {
        with %!indices.DELETE-KEY(key) -> \index {
            my \value = @!values[index];

            @!keys.splice:   index, 1;
            @!values.splice: index, 1;

            %!indices.AT-KEY(@!keys.AT-POS($_))-- for index .. @!keys.end;

            value
        }
    }

    method EXISTS-KEY(::?ROLE:D: \key) {
        %!indices.EXISTS-KEY(key)
    }

    method gist(::?ROLE:D:) {
        '{' ~ self.pairs.map( *.gist).join(", ") ~ '}'
    }

    method Str(::?ROLE:D:) {
        self.pairs.join(" ")
    }

    method raku(::?ROLE:D:) {
        self.perlseen(self.^name, {
          ~ self.^name
          ~ '.new('
          ~ self.pairs.map({$_<>.perl}).join(',')
          ~ ')'
        })
    }
}



my %m is Hash::Ordered = a => 42, b => 666;


Exports a C<Hash::Ordered> role that can be used to indicate the implementation
of a C<Hash> in which the keys are ordered the way the C<Hash> got initialized
or any later keys got added.


Since C<Hash::Ordered> is a role, you can also use it as a base for creating
your own custom implementations of hashes.


Source can be located at: https://github.com/lizmat/Hash-Ordered .
Comments and Pull Requests are welcome.


Ordered

The Raku Knowledge Base


=begin React :component<HeaderCol> :id<footer>  
=begin nested :!nested
=item1 B<Language>
    =item2 L<Get started|file:../getting-started/getting-started.podlite>
    =item2 L<Why Raku?|/doc/language/faq#Why-should-I-learn-Raku-What's-so-great-about-it>
    =item2 L<Try Raku|https://glot.io/new/raku>
    =item2 L<Raku cheat sheet|https://github.com/Raku/mu/blob/master/docs/Perl6/Cheatsheet/cheatsheet.txt>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<Raku on Exercism|https://exercism.org/tracks/raku>
    =item2 L<Wikipedia|https://en.wikipedia.org/wiki/Raku_(programming_language)>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=end nested
=begin nested :!nested

=item1 B<L<Documentation|/doc>>
    =item2 L<Getting started, Migration guides from other languages, & Tutorials | file:../doc/introduction.podlite>
    =item2 L<Language References|file:../doc/reference.podlite>
    =item2 L<Type Reference| file:../doc/types.podlite>
    =item2 L<Miscellaneous| file:../doc/miscellaneous.podlite>
    =item2 L<FAQs (Frequently Asked Questions)|/doc/language/faq>
    =item2 L<Community|/doc/language/community>
    =item2 L<The list of all documents|file:../doc/index.podlite>

=item1 B<Resources>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>

=end nested
=begin nested :!nested

=item1 B<Resoures>
    =item2 L<Download | file:../download/index.podlite>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=item1 B<Learning>
    =item2 L<The Raku Guide|https://raku.guide/>
    =item2 L<Wikibook |https://en.wikibooks.org/wiki/Raku_Programming>
    =item2 L<Books |https://perl6book.com/>
    =item2 L<Rosetta Code | https://www.raku.org/community/rosettacode>
    =item2 L<Learn Raku in Y minutes|https://learnxinyminutes.com/docs/raku/>
    =item2 L<Golfing |https://github.com/AlexDaniel/raku-golf-cheatsheet>
=end nested
=begin nested :!nested

=item1 B<Explore>
    =item2 L<Raku Blog Aggregator|https://planet.raku.org/>
    =item2 L<Rakudo Weekly|https://rakudoweekly.blog/>
    =item2 L<The Weekly Challenge |https://perlweeklychallenge.org/>
    =item2 L<Raku Advent Calendar|https://raku-advent.blog/>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>
    =item2 L<empty|#>

=end nested
=end React


=begin React :component<CookieConsent> :id<CookieConsent> :buttonCaption("Got it!")
=para
This website uses cookies for analytics.
=end React


README

NAME

SYNOPSIS

DESCRIPTION

AUTHOR

COPYRIGHT AND LICENSE

Hash::Ordered v0.0.2

Authors

License

Dependencies

Test Dependencies

Provides

Documentation